スパム対策として書込み時にID/PWを要求されますが、ローマ字で ほげ/ホゲ で書き込めるようになります。

サクラ風カラースチーム

  • 名前: 名無しさん
  • 投稿日: 2009-11-19 19:36:41 (木)

vimrc

" Vim color file
" Maintainer: Alexander Rodin <rodin.alexander@gmail.com>
"
" This theme is based on "desert256" theme by Henry So, Jr.
"
" I struggled with trying to parse the rgb.txt file to avoid the necessity of
" converting color names to #rrggbb form, but decided it was just not worth
" the effort.  Maybe someone seeing this may decide otherwise...

set background=light
if version > 580
    " no guarantees for version 5.8 and below, but this makes it stop
    " complaining
    hi clear
    if exists("syntax_on")
        syntax reset
    endif
endif
let g:colors_name="desert256"

if has("gui_running") || &t_Co == 88 || &t_Co == 256
    " functions {{{
    " returns an approximate grey index for the given grey level
    fun <SID>grey_number(x)
        if &t_Co == 88
            if a:x < 23
                return 0
            elseif a:x < 69
                return 1
            elseif a:x < 103
                return 2
            elseif a:x < 127
                return 3
            elseif a:x < 150
                return 4
            elseif a:x < 173
                return 5
            elseif a:x < 196
                return 6
            elseif a:x < 219
                return 7
            elseif a:x < 243
                return 8
            else
                return 9
            endif
        else
            if a:x < 14
                return 0
            else
                let l:n = (a:x - 8) / 10
                let l:m = (a:x - 8) % 10
                if l:m < 5
                    return l:n
                else
                    return l:n + 1
                endif
            endif
        endif
    endfun

    " returns the actual grey level represented by the grey index
    fun <SID>grey_level(n)
        if &t_Co == 88
            if a:n == 0
                return 0
            elseif a:n == 1
                return 46
            elseif a:n == 2
                return 92
            elseif a:n == 3
                return 115
            elseif a:n == 4
                return 139
            elseif a:n == 5
                return 162
            elseif a:n == 6
                return 185
            elseif a:n == 7
                return 208
            elseif a:n == 8
                return 231
            else
                return 255
            endif
        else
            if a:n == 0
                return 0
            else
                return 8 + (a:n * 10)
            endif
        endif
    endfun

    " returns the palette index for the given grey index
    fun <SID>grey_color(n)
        if &t_Co == 88
            if a:n == 0
                return 16
            elseif a:n == 9
                return 79
            else
                return 79 + a:n
            endif
        else
            if a:n == 0
                return 16
            elseif a:n == 25
                return 231
            else
                return 231 + a:n
            endif
        endif
    endfun

    " returns an approximate color index for the given color level
    fun <SID>rgb_number(x)
        if &t_Co == 88
            if a:x < 69
                return 0
            elseif a:x < 172
                return 1
            elseif a:x < 230
                return 2
            else
                return 3
            endif
        else
            if a:x < 75
                return 0
            else
                let l:n = (a:x - 55) / 40
                let l:m = (a:x - 55) % 40
                if l:m < 20
                    return l:n
                else
                    return l:n + 1
                endif
            endif
        endif
    endfun

    " returns the actual color level for the given color index
    fun <SID>rgb_level(n)
        if &t_Co == 88
            if a:n == 0
                return 0
            elseif a:n == 1
                return 139
            elseif a:n == 2
                return 205
            else
                return 255
            endif
        else
            if a:n == 0
                return 0
            else
                return 55 + (a:n * 40)
            endif
        endif
    endfun

    " returns the palette index for the given R/G/B color indices
    fun <SID>rgb_color(x, y, z)
        if &t_Co == 88
            return 16 + (a:x * 16) + (a:y * 4) + a:z
        else
            return 16 + (a:x * 36) + (a:y * 6) + a:z
        endif
    endfun

    " returns the palette index to approximate the given R/G/B color levels
    fun <SID>color(r, g, b)
        " get the closest grey
        let l:gx = <SID>grey_number(a:r)
        let l:gy = <SID>grey_number(a:g)
        let l:gz = <SID>grey_number(a:b)

        " get the closest color
        let l:x = <SID>rgb_number(a:r)
        let l:y = <SID>rgb_number(a:g)
        let l:z = <SID>rgb_number(a:b)

        if l:gx == l:gy && l:gy == l:gz
            " there are two possibilities
            let l:dgr = <SID>grey_level(l:gx) - a:r
            let l:dgg = <SID>grey_level(l:gy) - a:g
            let l:dgb = <SID>grey_level(l:gz) - a:b
            let l:dgrey = (l:dgr * l:dgr) + (l:dgg * l:dgg) + (l:dgb * l:dgb)
            let l:dr = <SID>rgb_level(l:gx) - a:r
            let l:dg = <SID>rgb_level(l:gy) - a:g
            let l:db = <SID>rgb_level(l:gz) - a:b
            let l:drgb = (l:dr * l:dr) + (l:dg * l:dg) + (l:db * l:db)
            if l:dgrey < l:drgb
                " use the grey
                return <SID>grey_color(l:gx)
            else
                " use the color
                return <SID>rgb_color(l:x, l:y, l:z)
            endif
        else
            " only one possibility
            return <SID>rgb_color(l:x, l:y, l:z)
        endif
    endfun

    " returns the palette index to approximate the 'rrggbb' hex string
    fun <SID>rgb(rgb)
        let l:r = ("0x" . strpart(a:rgb, 0, 2)) + 0
        let l:g = ("0x" . strpart(a:rgb, 2, 2)) + 0
        let l:b = ("0x" . strpart(a:rgb, 4, 2)) + 0

        return <SID>color(l:r, l:g, l:b)
    endfun

    " sets the highlighting for the given group
    fun <SID>X(group, fg, bg, attr)
        if a:fg != ""
            exec "hi " . a:group . " guifg=#" . a:fg . " ctermfg=" . <SID>rgb(a:fg)
        endif
        if a:bg != ""
            exec "hi " . a:group . " guibg=#" . a:bg . " ctermbg=" . <SID>rgb(a:bg)
        endif
        if a:attr != ""
            exec "hi " . a:group . " gui=" . a:attr . " cterm=" . a:attr
        endif
    endfun
    " }}}

    call <SID>X("VertSplit", "c2bfa5", "7f7f7f", "reverse")
    call <SID>X("Folded", "9999cc", "f4f4f4", "")
    call <SID>X("IncSearch", "708090", "f0e68c", "")
    call <SID>X("Visual", "3888ff", "ffffff", "reverse")
"    call <SID>X("Comment", "1C9518", "", "")
    call <SID>X("Comment", "20AD1B", "", "")
    call <SID>X("Constant", "5500ff", "", "")
    call <SID>X("String", "ff7777", "", "")
    call <SID>X("Float", "ff7777", "", "")
    call <SID>X("Boolean", "000080", "", "bold")
"    call <SID>X("Identifier", "98fb98", "", "none")
    call <SID>X("Statement", "000080", "", "bold")
    call <SID>X("PreProc", "20b5ff", "", "")
    call <SID>X("Type", "000080", "", "bold")
    call <SID>X("Special", "CDAB00", "", "")
    call <SID>X("Underlined", "0000cc", "", "")
    call <SID>X("Todo", "ff4500", "eeee00", "")

    " delete functions {{{
    delf <SID>X
    delf <SID>rgb
    delf <SID>color
    delf <SID>rgb_color
    delf <SID>rgb_level
    delf <SID>rgb_number
    delf <SID>grey_color
    delf <SID>grey_level
    delf <SID>grey_number
    " }}}
else
    " color terminal definitions
    hi VertSplit    ctermfg=lightgray ctermbg=gray cterm=reverse
    hi Folded       ctermfg=blue ctermbg=lightcyan
    hi IncSearch    ctermfg=lightgray ctermbg=yellow
    hi Visual       ctermfg=blue ctermbg=white cterm=reverse
    hi Comment      ctermfg=green
    hi Constant     ctermfg=blue
    hi String       ctermfg=red
    hi Float        ctermfg=red
    hi Boolean      ctermfg=darkblue cterm=bold
    hi Statement    ctermfg=darkblue cterm=bold
    hi PreProc      ctermfg=cyan
    hi Type         ctermfg=darkblue cterm=bold
    hi Special      ctermfg=brown
    hi Underlined   ctermfg=blue
    hi Todo         ctermfg=red ctermbg=yellow
endif
"set number color
hi FoldColumn		cterm=none		ctermfg=110		ctermbg=16		guibg=#FFFFFF
hi SignColumn		cterm=none		ctermbg=16		guibg=#FFFFFF
hi Folded			cterm=none		ctermfg=16		ctermbg=110		guifg=#FFFFFF	guibg=#87afd7
hi DiffText     gui=NONE guifg=#7800ff guibg=#FAEBD7
hi DiffChange   gui=NONE guifg=#dd0000 guibg=#ffe0f0
hi DiffDelete   gui=BOLD guifg=#0000ff guibg=#ccccff
hi DiffAdd      gui=NONE guifg=#000060 guibg=#d8d8ff
"==========================================================================================
" tabの表示色を設定(コンソールvim使用時はvimrcを編集すること) 
"highlight SpecialKey guifg=#808080
" eolの表示色を設定(コンソールvim使用時はvimrcを編集すること) 
highlight clear NonText
highlight NonText guifg=#808080
"======================================================================================================

" vim: set fdl=0 fdm=marker:

"zenkaku
highlight ZenkakuSpace cterm=underline ctermfg=lightblue guibg=#FFDAB9
au BufNewFile,BufRead * match ZenkakuSpace / /

  • いろいろぱくったのがまじってます -- 2010-02-10 22:25:57 (水)



トップ   編集 凍結 差分 バックアップ 添付 複製 名前変更 リロード   新規 一覧 単語検索 最終更新   ヘルプ   最終更新のRSS
Last-modified: 2014-10-14 (火) 01:13:17 (1350d)